fix qt_qpa_platformtheme, add volume OSD, adjust CPU and memory display

2026-08-08 20:21:48 -07:00
parent a0b1248d1e
commit a93def8e12
4 changed files with 128 additions and 21 deletions
@@ -0,0 +1,94 @@
+import QtQuick
+import QtQuick.Layouts
+import Quickshell
+import Quickshell.Services.Pipewire
+import Quickshell.Widgets
+
+Scope {
+    id: volumeOSD
+
+    // Bind the pipewire node so its volume will be tracked
+    PwObjectTracker {
+        objects: [Pipewire.defaultAudioSink]
+    }
+
+    Connections {
+        target: Pipewire.defaultAudioSink?.audio
+
+        function onVolumeChanged() {
+            volumeOSD.shouldShowOsd = true;
+            hideTimer.restart();
+        }
+    }
+
+    property bool shouldShowOsd: false
+
+    Timer {
+        id: hideTimer
+        interval: 1000
+        onTriggered: volumeOSD.shouldShowOsd = false
+    }
+
+    // The OSD window will be created and destroyed based on shouldShowOsd.
+    // PanelWindow.visible could be set instead of using a loader, but using
+    // a loader will reduce the memory overhead when the window isn't open.
+    LazyLoader {
+        active: volumeOSD.shouldShowOsd
+
+        PanelWindow {
+            anchors.bottom: true
+            margins.bottom: screen.height / 5
+            exclusiveZone: 0
+
+            implicitWidth: 400
+            implicitHeight: 50
+            color: "transparent"
+
+            // An empty click mask prevents the window from blocking mouse events.
+            mask: Region {}
+
+            Rectangle {
+                anchors.fill: parent
+                radius: height / 2
+                color: "#80000000"
+
+                RowLayout {
+                    anchors {
+                        fill: parent
+                        leftMargin: 10
+                        rightMargin: 15
+                    }
+
+                    IconImage {
+                        implicitSize: 30
+                        source: Quickshell.iconPath("audio-volume-high-symbolic")
+                    }
+
+                    Rectangle {
+                        // Stretches to fill all left-over space
+                        Layout.fillWidth: true
+
+                        implicitHeight: 10
+                        radius: 20
+                        color: "#50ffffff"
+                        Rectangle {
+                            anchors {
+                                left: parent.left
+                                top: parent.top
+                                bottom: parent.bottom
+                            }
+
+                            implicitWidth: parent.width * (Pipewire.defaultAudioSink?.audio.volume ?? 0)
+                            radius: parent.radius
+                        }
+                    }
+
+                    Text {
+                        text: `${Math.round((Pipewire.defaultAudioSink?.audio.volume ?? 0) * 100)}%`
+                        color: "white"
+                    }
+                }
+            }
+        }
+    }
+}